Nome dos eixos xx e yy na criação de gráfico em VBA

Olá a todos!
Atualmente estou a treinar subrotinas de VBA para me ambientar ao programa, pois futuramente poderei precisar.
A minha dúvida é a seguinte:

Criei a subrotina aqui demonstrada (objetivo-criar gráfico em vba) e ela corre perfeitamente. Agora queria saber como posso alterar os nomes das séries dos xx e dos yy (pus "x" e "y" respetivamente) indo buscar esses nomes que estão nas células A1 e B1 do excel? Para que, mais tarde, ao querer mudar o nome dos eixos seja necessário apenas mudar no excel e no gráfico altera automaticamente, não sendo necessário ir à subrotina alterar os nomes.

Obrigado pela atenção.
Christophe

Sub Gráfico()

Dim grafico As Chart
Dim xaxis As Range
Dim yaxis As Range

Set grafico = ActiveWorkbook.Charts.Add
Set grafico = grafico.Location(Where:=xlLocationAsObject, Name:="Folha1")
Set xaxis = Range("A2:A7")
Set yaxis = Range("B2:B7")

Dim ser As Series
Set ser = grafico.SeriesCollection.NewSeries

With ser
.Values = yaxis
.XValues = xaxis
End With

With grafico
.ChartType = xlXYScatter
.HasTitle = True
.ChartTitle.Text = "Gráfico_Teste"

.Axes(xlCategory).HasTitle = True
.Axes(xlCategory).AxisTitle.Text = "x"
.Axes(xlValue).HasTitle = True
.Axes(xlValue).AxisTitle.Text = "y"
.Axes(xlValue).MajorGridlines.Delete
.HasLegend = False

End With

End Sub

Bom dia!!

Já tentou..

Código:

Sub Gráfico()

Dim grafico As Chart
Dim xaxis As Range
Dim yaxis As Range

Set grafico = ActiveWorkbook.Charts.Add
Set grafico = grafico.Location(Where:=xlLocationAsObject, Name:="Folha1")
Set xaxis = Range("A2:A7")
Set yaxis = Range("B2:B7")

Dim ser As Series
Set ser = grafico.SeriesCollection.NewSeries

With ser
.Values = yaxis
.XValues = xaxis
End With

With grafico
.ChartType = xlXYScatter
.HasTitle = True
.ChartTitle.Text = "Gráfico_Teste"

.Axes(xlCategory).HasTitle = True
.Axes(xlCategory).AxisTitle.Text = [A1] '<--Alteração
.Axes(xlValue).HasTitle = True
.Axes(xlValue).AxisTitle.Text = [B1] '<--Alteração
.Axes(xlValue).MajorGridlines.Delete
.HasLegend = False

End With

End Sub

Bom dia!

Obrigado pela sua ajuda que me foi bastante útil. Porém, não existe uma maneira de, tal como nos valores que uso para o gráfico ao alterá-los o perfil do gráfico altera automaticamente? Enquanto que assim, alterando o conteudo das células A1 e B1 preciso de correr novamente a macro para aparecer as novas legendas.

Muito obrigado mais uma vez.

Cumprimentos,
Christophe Vieira

Boa noite!!

Neste caso você tem dois enventos Change e o Calculate

Exemplo

Código:

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Target.Worksheet.Range("A1:B1")) Is Nothing Then MinhaMacro
    'No lugar de MinhaMacro, coloque o nome de sua macro
End Sub

Att

Muito obrigado!

Bom dia!!

Que bom que seu problema foi resolvido!

Att